*  JieJie Microelectronics H-Spice Model Library
*  Filename	: JMSH1504AE7_H v.20220725.txt
*  Product Name   :  JMSH1504AE7 (TO-263-7L)
*  Configuration:	: Single N channel Device
*  Data Sheet Rev.	: 1.1
*  Release Date	: Aug1, 2022
*  Junction Temp (Tj): -40C ~ 150C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMSH1504AE7 D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
RD D 1 0.00187
RS S 3 1E-006
RG G 2 2.4
CGS 3 G 6.52E-9
EGD 12 0 2 1 1
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 1E-9
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
CDS D 3 POLY 7.39E-09 -2.06E-10 2.34E-12 -2.36E-14 3.20E-16 -2.47E-18 6.72E-21

.model NMOS NMOS
+LEVEL = 3                     tlev = 1                      tlevc = 0      
+acm = 3                       VMAX = 1.0752E9               ETA = 1E-4    
+VTO = 3.74                    TOX = 8E-10                   NSUB = 3.55E18  
+KP = 550                      U0 = 424                      KAPPA = 0.1  
+GAMMA = 0.3                   PHI = 0.55                    THETA = 1    
+BEX = -1                      TCV = 2.2E-3                  DELTA = 300    

.model DCGD D
+CJO = 1E-9                    VJ = 12.5                       M = 1.9   

.model DSUB D
+IS = 9E-12                    N = 1                         RS = 3E-3  
+BV = 155                      tlev = 0                      tlevc = 0  
+tref = 25                     eg = 1.201442                 keg = 1  
+gap1 = 3.999266E-4            gap2 = 1.108E3                xti = 0   
+cta = 0                       ctp = 0                       tcv = 0    
+tm1 = 0                       tm2 = 0                       tpb = 0    
+tphp = 0                      trs = 0                       ttt1 = 0     
+ttt2 = 0                      xtitun = 3  

.model DLIM D
+IS = 1E-4  
.ends JMSH1504AE7

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************